home *** CD-ROM | disk | FTP | other *** search
/ L' Effet Pommier 3 / L'Effet Pommier - Volume 03.iso / Graphismes / 3D / POV-Ray 3.0B5a PPC / POV-Ray 3.0B5a / POVSCN.Scenes / POVSCN / LEVEL2 / MTMAND.POV < prev    next >
Text File  |  1995-11-08  |  4KB  |  122 lines
  1. // Persistence Of Vision raytracer version 3.0 sample file.
  2. // File By Dan Farmer and Tim Wegner
  3.  
  4. // Low resolution versions of the images MTMAND.POT and MTMANDJ.GIF are
  5. // included so that you can render this scene, however in order to really
  6. // do the scene justice you should substitute higher resolution versions
  7. // of these images. MTMAND.PAR contains the fractal parameters to generate
  8. // both images using the DOS program FRACTINT.
  9.  
  10. #version 3.0
  11. global_settings { assumed_gamma 2.2 }
  12.  
  13. #include "shapes.inc"
  14. #include "colors.inc"
  15. #include "textures.inc"
  16. #declare PlanetColor = color red 0.65 green 0.65 blue 1.00
  17.  
  18. // The following constants simply make it easier to swap images of different
  19. // scales. Change ScaleX and ScaleZ if you generated the MTMAND.POT file at
  20. // a resolution different from 360 x 480 which Dan used.
  21.  
  22. #declare ScaleX = 0.5625    // 360/(pot image width) 
  23. #declare ScaleZ = 1.0       // 480/(pot image height) 
  24.  
  25. camera {
  26.    location <-150.0, 300.0, -650.0>
  27.    direction <0.0, 0.0, 4.0> // "Telephoto" lens, "compresses" distance 
  28.    up <0.0, 1.0, 0.0>        // The distance also seems to smooth the h-field 
  29.    right <4/3, 0.0, 0.0>
  30.    look_at <-40.0, 150.0, 0.0>
  31. }
  32.  
  33. // Define a couple of colors for the light sources.
  34. #declare MainLight = color red 0.8 green 0.8 blue 0.8
  35. #declare FillLight = color red 0.23 green 0.23 blue 0.25
  36. // Light source (main)
  37. light_source { <-400.0, 300.0, -60.0> color MainLight }
  38. // Light source ( shadow filler )
  39. light_source { <-50.0, 300.0, -60.0> color FillLight }
  40.  
  41. height_field  {
  42.    // 16 bit continuous potential Fractint fractal,
  43.    // floating point activated to allow a large bailout value
  44.    // Fractint parameters are:
  45.    //    type=mandel  
  46.    //    corners=-0.1992/-0.1099914/1.0000046/1.06707
  47.    //    float=yes
  48.    //    maxiter=1500
  49.    //    potential=255/2200/1000/16bit
  50.    //    savename=mtmand
  51.  
  52.    pot "mtmand.pot"
  53. // pot "mtmand.pot" smooth // <== try this for high resolution renders
  54. // gif "mtmand.gif" smooth // <== do this instead if no POT available
  55.    water_level 0.0
  56.  
  57.    pigment { White }
  58.    finish {
  59.       crand 0.025         // dither  - not used often, but this image needs it. 
  60.       ambient 0.2         // Very dark shadows
  61.       diffuse 0.8         // Whiten the whites
  62.       phong 0.75          // Fairly shiny
  63.       phong_size 100.0    // with tight highlights
  64.       specular 1.0
  65.       roughness 0.005
  66.    }
  67.  
  68.    scale <640, 256, 480>
  69.    scale <ScaleX, 0.5, ScaleZ> // Reduce the height, scale to 360 x 480 
  70.    translate <-180, 0.0, -240>  // Center the image by half of ScaleX and ScaleZ
  71. }
  72.  
  73. // Sky sphere 
  74. sphere { <0.0, 0.0, 0.0>, 1200.0
  75.    pigment {
  76.       gradient y     // Fade from yellow to orange to red to black 
  77.       color_map {
  78.          [0.00 0.10 color Yellow color Orange] // Yellow at horizon
  79.          [0.10 0.15 color Orange color Red]    // Fade to orange to red
  80.          [0.15 0.27 color Red   color Black ]  // then to dark red
  81.          [0.27 1.01 color Black  color Black ] // to Black at zenith
  82.       }
  83.       quick_color SummerSky
  84.       scale 1000                    // Big enough to surround the universe
  85.       translate <0.0, -240.0, 0.0>  // This ajusts for the viewer position 
  86.    }
  87.    finish {
  88.       ambient 1.0                 // Keep objects from casting shadows 
  89.       diffuse 0.0                 // All light comes from ambient sources 
  90.    }
  91. }
  92.  
  93.  
  94. // Planet
  95. sphere { <-95.0, 50.0, 600.0>, 35.0
  96.    pigment { PlanetColor }
  97.    normal {
  98.       bump_map {  // Bump texture with corresponding julia image
  99.          //    type=julia 
  100.          //    corners=-1.568/1.568/-1.176/1.176
  101.          //    params=-0.1545957/1.0335373 
  102.          //    float=yes 
  103.          //    maxiter=256
  104.          gif  "mtmandj.gif"
  105.          bump_size 15.0
  106.          interpolate 4.0  // Smooth the image
  107.       }
  108.        // mapped image is 1x1x1, with lower left corner at 0,0,0
  109.       translate <-0.5, -0.5, 0.0>        // Center the image at origin
  110.       scale <35.0, 35.0, 35.0>
  111.       rotate 95*z                        // Tweak the positioning a little
  112.    }
  113.    finish {
  114.       specular 0.35                    // Fairly "dull" surface
  115.       roughness 0.5                    // spread the highlight
  116.       ambient 0.0                      // Dark shadows
  117.       diffuse 0.75
  118.    }
  119. }
  120.  
  121. // end of file
  122.